Hi Adrian,
thanks for your bug report. The issue in OneLoopSimplify
should be now fixed.
The "official" way would be just to use TID. There is no need to use
OneLoop or OneLoopSimplify (which as you can see are not always 100%
working).
That is
InfParts := {B0[X__] -> FinB0[X] + 1/eps, A0[Y_] -> FinA0[Y] + Y/eps};
R = (1 + GA[5])/2;
L = (1 - GA[5])/2;
fad := FeynAmpDenominator;
pd[q_, m_] := PropagatorDenominator[Momentum[q, D], m];
DiagAden = fad[pd[k - p, mF], pd[k, mV], pd[k, 0]];
DiagAnum = -I (SPD[k, k] MTD[mu, nu] - FVD[k, mu] FVD[k, nu]) GAD[
mu].(Fal L + FalCC R).(GSD[k - p] + Mcc L + M R).GAD[
nu].(Fbe L + FbeCC R);
DiagA = ((4 Pi)^2/(2 Pi)^4) DiagAnum DiagAden;
ResA1 = TID[DiagA, k, ToPaVe -> True] // DiracSimplify;
(Collect2[ResA1, A0, B0] /. InfParts) //
FCReplaceD[#, D -> 4 - 2 eps] & //
Series[#, {eps, 0, 0}] & // Normal
Cheers,
Vladyslav
Am 11.10.2017 um 22:44 schrieb Adrian:
> Dear Vladyslav,
>
> I'm trying to calculate a diagram using three different approaches
>
> 1) OneLoop
> 2) TID -> OneLoop
> 3) OneLoopSimplify -> OneLoop
>
> The first two give a correct result while the last one does not (Mathematica 11.1 and the latest stable version of FeynCalc).
>
> Please note that the difference doesn't seem to be caused by the usual (D-4)/(D-4) terms. I guess that OneLoopSimplify treats chiral projections incorrectly. The example is appended below.
>
> By the way, what is the ``official way" of calculating one-loop integrals, 1,2,3 or maybe none of them?
>
> Best wishes,
> Adrian
>
>
> In[2]:= InfParts := {B0[X__] -> FinB0[X] + 1/eps,
> A0[Y_] -> FinA0[Y] + Y/eps};
>
> R = (1 + GA[5])/2;
> L = (1 - GA[5])/2;
> fad := FeynAmpDenominator;
> pd[q_, m_] := PropagatorDenominator[Momentum[q, D], m];
>
>
>
>
>
>
>
> In[9]:= DiagAnum = -I (SPD[k, k] MTD[mu, nu] -
> FVD[k, mu] FVD[k, nu]) GAD[
> mu].(Fal L + FalCC R).(GSD[k - p] + Mcc L + M R).GAD[
> nu].(Fbe L + FbeCC R);
>
> In[10]:= DiagAden = fad[pd[k - p, mF], pd[k, mV], pd[k, 0]];
>
> In[12]:= DiagA = ((4 Pi)^2/(2 Pi)^4) DiagAnum DiagAden ;
>
>
> (*First way*)
>
> In[16]:= ResA0 = OneLoop[k, DiagA];
>
> In[17]:= ResA0 = ResA0 // DiracSimplify
>
> In[18]:= ResA0 =
> ResA0 /. InfParts /. D -> 4 - 2 eps // Series[#, {eps, 0, 0}] & //
> Normal
>
>
> (*Second way*)
>
>
> In[30]:= ResA = OneLoopSimplify[DiagA, k];
>
> In[20]:= ResA = OneLoop[k, ResA];
>
> In[21]:= ResA = ResA // DiracSimplify;
>
> In[22]:= ResA =
> ResA /. InfParts /. D -> 4 - 2 eps // Series[#, {eps, 0, 0}] & //
> Normal
>
>
> (*Third way*)
>
>
> In[23]:= ResA1 = TID[DiagA, k];
>
> In[24]:= ResA1 = OneLoop[k, ResA1];
>
> In[25]:= ResA1 = ResA1 // DiracSimplify;
>
> In[26]:= ResA1 =
> ResA1 /. InfParts /. D -> 4 - 2 eps // Series[#, {eps, 0, 0}] & //
> Normal
>
>
> (*Comparison*)
>
> In[27]:= ResA1 - ResA0 // Simplify
>
> Out[27]= 0
>
> In[28]:= Limit[eps ( ResA1 - ResA), eps -> 0] // Simplify
>
> Out[28]= -(3/
> 2) (FalCC M - Fal Mcc) (Fbe (-1 + DiracGamma[5]) +
> FbeCC (1 + DiracGamma[5]))
>
This archive was generated by hypermail 2b29 : 09/04/20-12:55:05 AM Z CEST