Date: 11/03/14-11:32:18 PM Z

Hi,

it is not a bug. For the q qbar -> q qbar computation, there are two
things that one should take into account:

1) The relative sign between the two diagrams is a minus. Remember
Bhabha scattering (e+ e⁻ -> e+ e-)? There you have precisely the same
situation with four external fermions.

2) When you are dealing with the diagrams that have more than two
external quarks, you must pay attention to the color flow! Suppose that
the incoming q and qbar carry the colors i and j, while the colors of
the outgoing quark and antiquark are k and l. Then the color structure
of the first (annihilation) diagram is T^A_ij T^A_lk, where A is the
adjoint color index and i,j,k,l are the fundamental color indices.
You see that this is not a product of two SUNT matrices. For the other
(scattering) diagram you have T^A_ik T^A_jk. Only when you compute the
matrix element squared you obtain something that you can hit with
SUNSimplify. For the product of the first or the second diagram with
itself you get

T^A_ij T^A_lk T^B_ji T^B_kl = SUNTrace[SUNT[A, B]]*SUNTrace[SUNT[A, B]]

But for the cross terms you get

T^A_ij T^A_lk T^B_ki T^B_jl = SUNTrace [SUNT[A,B,A,B]]

The first expression evaluates to 2, while the second gives you -2/3!

Unfortunately, the current FeynCalc version doesn't support working with
explicit color indices in the *fundamental* representation. It is on my
ToDo list, but I don't know when I'll have time to add that.

However, as long as you pay attention to the way how the quark colors
flow in the diagram, you can always do these kind of things by hand.

Here is the corrected version of your code that return the right result.

<< HighEnergyPhysics`FeynCalc`
ClearScalarProducts;
{ScalarProduct[p1, p1] =
ScalarProduct[p2, p2] =
ScalarProduct[p3, p3] = ScalarProduct[p4, p4] = 0,
ScalarProduct[p1, p2] = ScalarProduct[p3, p4] = s/2,
ScalarProduct[p1, p3] = ScalarProduct[p2, p4] = -t/2,
ScalarProduct[p1, p4] = ScalarProduct[p2, p3] = -u/2};
ScPr[p_, m_] := -I/(ScalarProduct[p] - m^2) // ExpandScalarProduct;
ftrace = {DiracTrace -> Tr2, D -> 4};
SUNN = 3;
SetOptions[SUNSimplify, SUNNToCACF -> False];
qav = 6;
f1 = (SpinorVBar[p2, 0].QGV[\[Alpha], k].SpinorU[p1, 0] ScPr[p1 + p2,
0] SpinorUBar[p3, 0].QGV[\[Alpha], k].SpinorV[p4, 0] //
Explicit) /. {SUNT[x_] -> 1};
f2 = -(SpinorUBar[p3, 0].QGV[\[Alpha], k].SpinorU[p1, 0] ScPr[p1 - p3,
0] SpinorVBar[p2, 0].QGV[\[Alpha], k].SpinorV[p4, 0] //
Explicit) /. {SUNT[x_] -> 1};
f1s = (SpinorUBar[p1, 0].QGV[\[Beta], l].SpinorV[p2,
0] (-ScPr[p1 + p2, 0]) SpinorVBar[p4, 0].QGV[\[Beta],
l].SpinorU[p3, 0] // Explicit) /. {SUNT[x_] -> 1};
f2s = -(SpinorUBar[p1, 0].QGV[\[Beta], l].SpinorU[p3,
0] (-ScPr[p1 - p3, 0]) SpinorVBar[p4, 0].QGV[\[Beta],
l].SpinorV[p2, 0] // Explicit) /. {SUNT[x_] -> 1};
Msq = FermionSpinSum[
SUNSimplify[(f1 f1s) SUNTrace[SUNT[a, b]]*
SUNTrace[SUNT[a, b]] +
(f1 f2s) SUNTrace[SUNT[a, b, a, b]] +
(f1s f2) SUNTrace[SUNT[a, b, a, b]] +
(f2 f2s) SUNTrace[SUNT[a, b]]*SUNTrace[SUNT[a, b]]] //
Explicit // Expand]/(qav^2 Gstrong^4) /. ftrace //
Contract // Simplify // SUNSimplify // Expand
standard = 4/9 ((s^2 + u^2)/t^2 + (u^2 + t^2)/s^2 - 2/3 u^2/(s t))
TrickMandelstam[Msq - standard, {s, t, u, 0}]

Cheers,

Am 03.11.2014 um 06:06 schrieb L.X.Xu:
> hi,
> the result of (quark,quarkbar->quark,quarkbar) obtained by FeynCalc is not correct, one term of the result differ by a minus sign from the correct. We can just find the correct at page 196 of Langacker's book<the standard model and beyond> or page 571 of Peskin EQ(17,70).
> is there an problem of my code or a bug?
>
> I'm appreciate the help!
> Here is my code:
> Quit;
> << HighEnergyPhysics`FeynCalc`
>
> ClearScalarProducts;
> {ScalarProduct[p1, p1] =
> ScalarProduct[p2, p2] =
> ScalarProduct[p3, p3] = ScalarProduct[p4, p4] = 0,
> ScalarProduct[p1, p2] = ScalarProduct[p3, p4] = s/2,
> ScalarProduct[p1, p3] = ScalarProduct[p2, p4] = -t/2,
> ScalarProduct[p1, p4] = ScalarProduct[p2, p3] = -u/2
> };
> ScPr[p_, m_] := -I/(ScalarProduct[p] - m^2) // ExpandScalarProduct;
> ftrace = {DiracTrace -> Tr2, D -> 4};
> SUNN = 3;
> SetOptions[SUNSimplify, SUNNToCACF -> False];
> qav = 6;
>
> f1 = SpinorVBar[p2, 0].QGV[\[Alpha], k].SpinorU[p1, 0] ScPr[p1 + p2,
> 0] SpinorUBar[p3, 0].QGV[\[Alpha], k].SpinorV[p4, 0] // Explicit;
> f2 = SpinorUBar[p3, 0].QGV[\[Alpha], k].SpinorU[p1, 0] ScPr[p1 - p3,
> 0] SpinorVBar[p2, 0].QGV[\[Alpha], k].SpinorV[p4, 0] // Explicit;
> f = f1 + f2
> f1s = SpinorUBar[p1, 0].QGV[\[Beta], l].SpinorV[p2,
> 0] (-ScPr[p1 + p2, 0]) SpinorVBar[p4, 0].QGV[\[Beta],
> l].SpinorU[p3, 0] // Explicit;
> f2s = SpinorUBar[p1, 0].QGV[\[Beta], l].SpinorU[p3,
> 0] (-ScPr[p1 - p3, 0]) SpinorVBar[p4, 0].QGV[\[Beta],
> l].SpinorV[p2, 0] // Explicit;
> fstar = f1s + f2s
>
> Msq = FermionSpinSum[
> f fstar // Explicit // Expand]/(qav^2 Gstrong^4) /. ftrace //
> Contract // Simplify // SUNSimplify // Expand
>
> standard = 4/9 ((s^2 + u^2)/t^2 + (u^2 + t^2)/s^2 - 2/3 u^2/(s t))
> TrickMandelstam[Msq - standard, {s, t, u, 0}]
>

This archive was generated by hypermail 2b29 : 07/20/18-10:20:04 PM Z CEST